Zahid,
If your data is in a plane at a constant Z, but all the planes are in one zone, you can create new zones with just those points in a single Z plane. You can also collect points in a range of Z coordinates. If you know at which node location the Z-plane coordinate changes, you can use the Data->Extract Zone-> subzone... option in the main menu to extract a range of I-direction points into a single zone. Once in a single zone, you can then switch to the X,Y plane in 2D and triangulate the zone to generate the contours you seek. On the other hand, if you want a range of Z-coordinates to be in a single plane, then you have to use a macro to query each point and determine if the Z-coordinate is within an acceptable range for Z. Then you can triangulate the new zone.
Furthermore, if the points you have are in order such that the Z-coordinate does not change for the entire plane of points, until the next plane begins, you can also use a macro to post process the 1D zone into multiple zones by switching to a new zone when the Z-coordinate changes. An example macro would be:
Code: Select all
#!MC 1100
$!GetVarNumByName |Zvar|
Name = "Z"
# Determine the number of points in each zone and
# create a new zone for each one with the contents
# extracted from the root zone (1).
$!VarSet |NumPlanes| = 0
$!Loop |MaxI|
$!GetFieldValue |Zpt|
Zone = 1
Var = |Zvar|
Index = |loop|
$!If |loop| == 1
$!VarSet |Zold| = |Zpt|
$!VarSet |NumPts| = 1
$!Else
$!If |Zold| == |Zpt|
$!VarSet |NumPts| += 1
$!Else
$!VarSet |NumPlanes| += 1
$!VarSet |BegPt| = (|loop|-|NumPts|)
$!VarSet |EndPt| = (|loop|-1)
$!DuplicateZone
SourceZone = 1
IRange
{
Min = |BegPt|
Max = |Endpt|
}
$!RenameDatasetZone
Zone = |NumZones|
Name = "Z=|Zold|"
$!VarSet |NumPts| = 1
$!VarSet |Zold| = |Zpt|
$!EndIf
$!EndIf
$!EndLoop
$!VarSet |NumPlanes| += 1
$!VarSet |BegPt| = (|loop|-|NumPts|)
$!VarSet |EndPt| = (|loop|-1)
$!DuplicateZone
SourceZone = 1
IRange
{
Min = |BegPt|
Max = |Endpt|
}
$!RenameDatasetZone
Zone = |NumZones|
Name = "Z=|Zold|"
When this macro is finished, you should have multiple zones with each one as a separate zone for a specific Z coordinate. I'll leave the rest up to you to determine how to cast the data into an X-Y plane and triangulate the data. Note that all of this additional work can be done in the macro so that at the end, you have a set of zones with pressure contours showing.
Good Luck.
Steve...
Aerospace Research Engineer
Aerothermodynamics Branch
NASA Langley Research Center